Chỉ định các trình xử lý sự kiện để điều khiển trên biểu mẫu người dùng được tạo động trong VBA

Question

Tôi đã tìm thấy nhiều tài nguyên trên internet thực hiện gần như những gì tôi muốn thực hiện, nhưng không hoàn toàn.Tôi có một phạm vi được đặt tên là "danh sách ban ngày". Đối với mỗi ngày trong danh sách ban ngày, tôi muốn tạo một nút trên biểu mẫu người dùng sẽ chạy macro cho ngày đó. Tôi có thể add the buttons dynamically nhưng không biết cách vượt qua daycell.text từ phạm vi được đặt tên, tới nút, tới trình xử lý sự kiện, tới macro: S Heres mã tôi phải tạo biểu mẫu người dùng:

Sub addLabel() 
ReadingsLauncher.Show vbModeless 
Dim theLabel As Object 
Dim labelCounter As Long 
Dim daycell As Range 
Dim btn As CommandButton 
Dim btnCaption As String 


For Each daycell In Range("daylist") 
    btnCaption = daycell.Text 
    Set theLabel = ReadingsLauncher.Controls.Add("Forms.Label.1", btnCaption, True) 
    With theLabel 
     .Caption = btnCaption 
     .Left = 10 
     .Width = 50 
     .Top = 20 * labelCounter 
    End With 

    Set btn = ReadingsLauncher.Controls.Add("Forms.CommandButton.1", "runButton", True) 
    With btn 
     .Caption = "Run Macro for " & btnCaption 
     .Left = 80 
     .Width = 80 
     .Top = 20 * labelCounter 
    ' .OnAction = "btnPressed" 
    End With 

    labelCounter = labelCounter + 1 
Next daycell 

End Sub 

để khắc phục vấn đề trên tôi đang nhắc nhở người dùng gõ ngày họ muốn chạy (ví dụ Day1) và chuyển thông tin này đến vĩ mô và hoạt động:

Sub B45runJoinTransactionAndFMMS() 


loadDayNumber = InputBox("Please type the day you would like to load:", Title:="Enter Day", Default:="Day1") 

Call JoinTransactionAndFMMS(loadDayNumber) 

End Sub 

Sub JoinTransactionAndFMMS(loadDayNumber As String) 
xDayNumber = loadDayNumber 

Sheets(xDayNumber).Activate 
-Do stuff 

End Sub 

vì vậy, đối với mỗi runButtons của tôi, nó cần hiển thị daycell.text và chạy macro sử dụng cùng văn bản đó làm tham số để chọn trang tính để thực hiện công việc của nó.

Mọi trợ giúp đều tuyệt vời. Ive thấy phản ứng tự động viết mã vba, để xử lý các macro, nhưng tôi tin rằng phải có someway nó có thể được thực hiện một chút thanh lịch hơn thông qua các thông số đi qua, chỉ cần không chắc chắn như thế nào. Rất cám ơn trước!

Answer 1

Tôi biết bạn đã chấp nhận một giải pháp bây giờ mà sẽ làm việc cho bạn và là đơn giản hơn nhiều so với bên dưới, nhưng nếu bạn quan tâm, đây sẽ là câu trả lời trực tiếp hơn đến câu hỏi của bạn.

Bạn cần tạo lớp để xử lý các lần nhấp nút, mỗi khi nút được nhấp, nó sử dụng sự kiện trong lớp, bạn chỉ cần thực hiện thao tác này một lần sau đó tạo phiên bản mới cho mỗi nút. Để ngăn chặn các lớp này đi ra khỏi phạm vi và bị mất, họ cần lưu trữ trong một tuyên bố cấp lớp. Ở bên dưới tôi đã di chuyển mã của bạn xung quanh một chút.

Trong mô-đun lớp (tôi đã gọi nó là cButtonHandler)

Public WithEvents btn As MSForms.CommandButton 

Private Sub btn_Click() 
    MsgBox btn.Caption 
End Sub 

Với sự kiện được sử dụng vì nó cho phép bạn sử dụng hầu hết các sự kiện cho sự kiểm soát. Tôi đã chuyển mã thế hệ nút vào userform như sau:

Dim collBtns As Collection 

Private Sub UserForm_Initialize() 

Dim theLabel As Object 
Dim labelCounter As Long 
Dim daycell As Range 
Dim btn As CommandButton 
Dim btnCaption As String 
'Create a variable of our events class 
Dim btnH As cButtonHandler 
'Create a new collection to hold the classes 
Set collBtns = New Collection 

For Each daycell In Range("daylist") 
    btnCaption = daycell.Text 
    Set theLabel = ReadingsLauncher.Controls.Add("Forms.Label.1", btnCaption, True) 
    With theLabel 
     .Caption = btnCaption 
     .Left = 10 
     .Width = 50 
     .Top = 20 * labelCounter 
    End With 

    Set btn = ReadingsLauncher.Controls.Add("Forms.CommandButton.1", "runButton", True) 
    With btn 
     .Caption = "Run Macro for " & btnCaption 
     .Left = 80 
     .Width = 80 
     .Top = 20 * labelCounter 
     'Create a new instance of our events class 
     Set btnH = New cButtonHandler 
     'Set the button we have created as the button in the class 
     Set btnH.btn = btn 
     'Add the class to the collection so it is not lost 
     'when this procedure finishes 
     collBtns.Add btnH 
    End With 

    labelCounter = labelCounter + 1 
Next daycell 


End Sub 

Sau đó chúng ta có thể gọi useform từ một thói quen riêng biệt:

Sub addLabel() 
ReadingsLauncher.Show vbModeless 

End Sub 

Lớp học trong VBA không đặc biệt tốt được đề cập trong nhiều VBA sách (nói chung bạn cần phải đọc sách VB6 để có được một sự hiểu biết), tuy nhiên một khi bạn hiểu họ và làm thế nào họ làm việc, họ trở nên vô cùng hữu ích :)

Hy vọng điều này sẽ giúp

EDIT - để giải quyết các truy vấn bổ sung

Để tham chiếu đến các đối tượng trong bộ sưu tập, việc này được thực hiện thông qua khóa hoặc chỉ mục.Để sử dụng chìa khóa, bạn cần phải thêm nó khi bạn thêm các mục vào bộ sưu tập, vì vậy:

collBtns.Add btnH 

sẽ trở thành

collBtns.Add btnH, btnCaption 

Vì lý do này, phím phải là duy nhất. Sau đó bạn có thể tham khảo như sau:

'We refer to objects in a collection via the collection's key 
'Or by it's place in the collection 
'So either: 
MsgBox collBtns("Monday").btn.Caption 
'or: 
MsgBox collBtns(1).btn.Caption 
'We can then access it's properties and methods 
'N.B you won't get any intellisense 
collBtns("Monday").btn.Enabled = False 

Bạn cũng có thể bổ sung thêm các thuộc tính/phương pháp để lớp học của bạn nếu cần thiết, vì vậy ví dụ:

Public WithEvents btn As MSForms.CommandButton 

Private Sub btn_Click() 
    MsgBox btn.Caption 
End Sub 

Public Property Let Enabled(value As Boolean) 
    btn.Enabled = value 
End Property 

sau đó có thể được truy cập:

collBtns("Monday").Enabled = False 

Điều này có hữu ích không? Để đọc thêm tôi sẽ chỉ cho bạn hướng tới trang web của Chip Pearson, anh ấy có nhiều nội dung tuyệt vời về hầu hết các chủ đề http://www.cpearson.com/excel/Events.aspx

Chỉ cần nhớ rằng VBA dựa trên VB6 vì vậy không phải là một ngôn ngữ OO hoàn toàn chính thức, không hỗ trợ kế thừa theo nghĩa thông thường, chỉ có giao diện thừa kế

Hope this helps :)

Answer 2

Ví dụ về đánh bắt nhấp chuột vào trang tính. Đặt này trong module bảng:

Private Sub Worksheet_SelectionChange(ByVal Target As Range) 
    ' e.g., range(A1:E1) is clicked 
    If Not Application.Intersect(Target, Range("A1:E1")) Is Nothing Then 
    MsgBox "You clicked " & Target.Address 
    End If 
End Sub