Set CMD tiêu đề để một dấu gạch chéo và một dấu hỏi (batch)

Question

Tôi tự hỏi nếu nó có thể thay đổi tiêu đề cửa sổ CMD để /?

Tôi đã cố gắng sử dụng ^/?, ^/^?, và "/?" nhưng không ai trong số họ dường như hoạt động.

Bất kỳ ai cũng có bất kỳ đề xuất nào?

Cảm ơn

Answer 1

Có thể thêm một số ký tự vô hình.
Ý tưởng được lấy từ @npocmaka SO: How can I set set a title that start with coma,semicolon or equal sign?
Vấn đề của tiêu đề có dấu phẩy bắt đầu cũng có thể được giải quyết bằng ký tự LF, nhưng trong trường hợp của bạn, LF không giúp bất kỳ đâu trong chuỗi.

@echo off 

(set LF=^ 
%=empty=% 
) 

::Create a FS variable 
call :hexprint "0x1C" FS 

title /%FS%? 
exit /b 

:hexPrint string [rtnVar] 
    for /f eol^=^%LF%%LF%^ delims^= %%A in (
    'forfiles /p "%~dp0." /m "%~nx0" /c "cmd /c echo(%~1"' 
) do if "%~2" neq "" (set %~2=%%A) else echo(%%A 
exit /b 

Answer 2

@ECHO OFF 
if "%~1"=="_SO42546112_" (
    shift 
) else (
    start "/?" cmd /D /K ""%~f0" "_SO42546112_"" 
    exit 
) 

Để khởi động một mớiCMD command prompt với /? tiêu đề cửa sổ, nhấp đúp trên .bat kịch bản.

---

Để chạy một kịch bản .bat với /? tiêu đề cửa sổ, sử dụng trên khái niệm ví dụ như sau:

@ECHO OFF 
SETLOCAL EnableExtensions 

rem self wrapper - start 
if "%~1"=="_SO42546112_" (
    shift 
) else (
    start "/?" cmd /D /C ""%~f0" "_SO42546112_" %*" 
    exit /B 
    rem ↑↑ omit the `/B` switch to close calling `cmd` window 
) 
rem self wrapper - end 

rem check whether the self wrapper works - start 
echo 1st "%~1" 
echo 2nd "%~2" 
echo 3rd "%~3" 
echo all %* 
pause 
rem check whether the self wrapper works - end 

rem original script continues here: