Làm cách nào để sử dụng các hằng số từ mô-đun Perl?

Question

Nếu tôi xác định một hằng số trong một mô-đun Perl, làm cách nào để sử dụng hằng số đó trong chương trình chính của tôi? (Hoặc làm cách nào để gọi hằng số đó trong chương trình chính?)

Answer 1

Có thể xuất các hằng số giống như các biểu tượng gói khác. Sử dụng Exporter mô-đun tiêu chuẩn, bạn có thể xuất hằng từ một gói phần mềm như thế này:

package Foo; 
use strict; 
use warnings; 

use base 'Exporter'; 

use constant CONST => 42; 

our @EXPORT_OK = ('CONST'); 

1; 

Sau đó, trong một kịch bản khách hàng (hoặc mô-đun khác)

use Foo 'CONST'; 
print CONST; 

Bạn có thể sử dụng %EXPORT_TAGS băm (xem Tài liệu của nhà xuất khẩu) để xác định các nhóm hằng số có thể được xuất với một đối số nhập duy nhất.

Cập nhật: Dưới đây là ví dụ về cách sử dụng tính năng %EXPORT_TAGS nếu bạn có nhiều hằng số.

use constant LARRY => 42; 
use constant CURLY => 43; 
use constant MOE => 44; 

our @EXPORT_OK = ('LARRY', 'CURLY', 'MOE'); 
our %EXPORT_TAGS = (stooges => [ 'LARRY', 'CURLY', 'MOE' ]); 

Sau đó, bạn có thể nói

use Foo ':stooges'; 
print "$_\n" for LARRY, CURLY, MOE; 

Answer 2

Constants chỉ là tàu ngầm với nguyên mẫu trống, vì vậy họ có thể được xuất khẩu giống như bất kỳ phụ khác.

# file Foo.pm 
package Foo; 
use constant BAR => 123; 
use Exporter qw(import); 
our @EXPORT_OK = qw(BAR); 


# file main.pl: 
use Foo qw(BAR); 
print BAR; 

Answer 3

Để mở rộng trên các câu trả lời trước đó, vì hằng số thực sự chỉ là tàu ngầm, bạn có thể cũng gọi cho họ trực tiếp:

use Foo; 
print Foo::BAR; 

Answer 4

Bạn có thể muốn xem xét sử dụng Readonly thay vì liên tục.

Answer 5

package Foo; 
use Readonly; 
Readonly my $C1 => 'const1'; 
Readonly our $C2 => 'const2'; 
sub get_c1 { return $C1 } 
1; 

perl -MFoo -e 'print "$_\n" for Foo->get_c1, $Foo::C2' 

Answer 6

Để thêm vào túi thủ thuật, vì hằng số chỉ là một chương trình con, bạn thậm chí có thể gọi nó là phương thức lớp.

package Foo; 
use constant PI => 3.14; 

print Foo->PI; 

Nếu bạn có nhiều hằng số, đây là cách tốt nhất để truy cập thường xuyên mà không phải xuất tất cả. Tuy nhiên, không giống như Foo::PI hoặc xuất PI, Perl sẽ không biên dịch Foo->PI do đó bạn phải chịu chi phí của một cuộc gọi phương thức (có thể không quan trọng).