Cách xem loại biến trong PL/SQL?

Question

Có một hàm trong PL/SQL để hiển thị loại chính xác của biến, như hàm DUMP trong SQL không?

Tôi đã thử những điều sau

DECLARE 
    l_variable INTEGER := 1; 
BEGIN 
    DBMS_OUTPUT.PUT_LINE (DUMP (l_variable)); 
END; 

Nhưng nó mang lại cho các lỗi sau:

PLS-00204: function or pseudo-column 'DUMP' may be used inside a SQL statement only

Answer 1

Bạn có thể tạo chức năng này sử dụng PL/Scope. Nhưng nó sẽ không hoạt động với các khối ẩn danh và bạn sẽ cần phải tham chiếu biến này dưới dạng chuỗi.

create or replace function get_plsql_type_name 
(
    p_object_name varchar2, 
    p_name varchar2 
) return varchar2 is 
    v_type_name varchar2(4000); 
begin 
    select reference.name into v_type_name 
    from user_identifiers declaration 
    join user_identifiers reference 
     on declaration.usage_id = reference.usage_context_id 
     and declaration.object_name = reference.object_name 
    where 
     declaration.object_name = p_object_name 
     and declaration.usage = 'DECLARATION' 
     and reference.usage = 'REFERENCE' 
     and declaration.name = p_name; 

    return v_type_name; 
end; 
/

Ví dụ:

alter session set plscope_settings = 'IDENTIFIERS:ALL'; 

create or replace type my_weird_type is object 
(
    a number 
); 

create or replace procedure test_procedure is 
    var1 number; 
    var2 integer; 
    var3 my_weird_type; 
    subtype my_subtype is pls_integer range 42 .. 43; 
    var4 my_subtype; 
begin 
    dbms_output.put_line(get_plsql_type_name('TEST_PROCEDURE', 'VAR1')); 
    dbms_output.put_line(get_plsql_type_name('TEST_PROCEDURE', 'VAR2')); 
    dbms_output.put_line(get_plsql_type_name('TEST_PROCEDURE', 'VAR3')); 
    dbms_output.put_line(get_plsql_type_name('TEST_PROCEDURE', 'VAR4')); 
end; 
/

begin 
    test_procedure; 
end; 
/

NUMBER 
INTEGER 
MY_WEIRD_TYPE 
MY_SUBTYPE 

Answer 2

declare 
    a number(10,3); 
    type_info varchar2(400); 
begin 
    a := 55.5; 
    select dump(a) into type_info from dual; 
    DBMS_OUTPUT.PUT_LINE(type_info); 
end; 

Answer 3

như bạn nên để ý, DUMP là một chức năng quá tải. nó có 3 tình trạng quá tải.

Vì vậy, bạn có thể mô phỏng cùng một điều trong mã của mình.

function myDump (x Varchar2) return varchar2 is begin return('string') ; end ; 
function myDump (x number) return varchar2 is begin return('integer') ; end ; 
function myDump (x date) return varchar2 is begin return('date') ; end ; 

mã ở trên có thể không hoạt động đúng nhưng nên cung cấp cho bạn ý tưởng về cách giải quyết vấn đề.

Tôi hy vọng rằng điều này sẽ đáp ứng các yêu cầu của bạn.

Lưu ý; bạn có thể đặt các chức năng này trong một Gói và sử dụng chúng cho phù hợp.