Adobe Flex: Nhãn gói trong nhãn nút

Question

Nút Flex chuẩn không cho phép gói văn bản nhãn thành từ. Tôi đọc trên internet rằng có một số cách không có giấy tờ để xử lý việc này nhưng tôi không yêu cầu họ làm việc. Nếu ai đó có thể gửi cho tôi một ví dụ nhỏ sẽ là tuyệt vời!

Answer 1

Về cơ bản, bạn cần thiết lập một số thuộc tính được bảo vệ trên điều khiển TextField của nút (multiLine và wordWrap), mà bạn không thể thực hiện mà không mở rộng lớp Button. Vì vậy, nếu bạn tạo một lớp mới mở rộng nút và thiết lập các thuộc tính và không một công việc ít để làm cho mọi việc đo lường một cách chính xác:

package 
{ 
    import flash.text.TextFieldAutoSize; 
    import mx.controls.Button; 

    public class WrappingButton extends Button 
    { 


     public function WrappingButton() 
     { 
      super(); 
     } 

     override protected function createChildren():void 
     { 
      super.createChildren(); 

      textField.multiline = true; 
      textField.wordWrap = true; 
      textField.autoSize = TextFieldAutoSize.CENTER; 
     } 

     override protected function updateDisplayList(unscaledWidth:Number, unscaledHeight:Number):void 
     { 
      super.updateDisplayList(unscaledWidth, unscaledHeight); 
      textField.y = (this.height - textField.height) >> 1; 

      height = textField.height + getStyle("paddingTop") + getStyle("paddingBottom"); 
     } 
    } 
} 

... bạn có thể thả điều khiển mà thành MXML của bạn như vậy:

<?xml version="1.0" encoding="utf-8"?> 
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" xmlns:local="*"> 

    <local:WrappingButton label="The quick brown fox jumped over the lazy dog." width="100" paddingTop="10" paddingBottom="10" /> 

</mx:Application> 

Hy vọng điều đó sẽ hữu ích! Đăng lại với câu hỏi nếu bạn có.

Answer 2

Cố gắng sử dụng 


Tôi đang sử dụng

<s:Button label="Top two&#13;states result" height="100%" width="100%" icon="@Embed(source='assets/bar.png')" chromeColor="#A3F4FD"/> 

và nó nhãn đa dòng.