Làm thế nào để chuyển đổi std :: string thành NSString?

Question

Xin chào Tôi đang cố gắng chuyển đổi một tiêu chuẩn std::string thành một số NSString nhưng tôi không có nhiều may mắn.

tôi có thể chuyển đổi thành công từ một NSString đến một std::string với đoạn mã sau

NSString *realm = @"Hollywood"; 
std::string REALM = [realm cStringUsingEncoding:[NSString defaultCStringEncoding]]; 

Tuy nhiên tôi nhận được một lỗi thời gian biên dịch khi tôi thử như sau

NSString *errorMessage = [NSString stringWithCString:REALM encoding:[NSString defaultCStringEncoding]]; 

Các lỗi tôi nhận được là

Cannot convert 'std::string' to 'const char*' in argument passing 

Tôi có thiếu gì đó ở đây không?

Xin cảm ơn trước.

Answer 1

Nhận c-string ra khỏi std :: string cho chuyển đổi:

NSString *errorMessage = [NSString stringWithCString:REALM.c_str() 
            encoding:[NSString defaultCStringEncoding]]; 

Answer 2

Thứ nhất, bạn đã có được sử dụng Objective-C++ để làm việc này một chút nào; Cách dễ nhất để đảm bảo đó là đổi tên tất cả *.m tập tin của bạn để *.mm

Bởi đến nay có thể sử dụng hầu hết các cách thủ công (không bị phản đối) nhận được một C++ std::string thành một NSString là với:

std::string param; // <-- input 
NSString* result = [NSString stringWithUTF8String:param.c_str()]; 
NSString* alternative = [[NSString alloc] initWithUTF8String:param.c_str()]; 

này sẽ làm việc trong hầu hết các trường hợp - và nếu bạn không thực hiện phát hiện và chuyển đổi mã cụ thể, UTF-8 sẽ cung cấp cho bạn kết quả tốt cho việc có các ký tự không phải là chữ latin ”.

Nếu bạn đang tạo một ứng dụng lớn hơn hoặc bạn không phải là người duy nhất làm việc trên ứng dụng đó, tuy nhiên - có thể bạn sẽ muốn có thứ dễ áp ​​dụng hơn.

Phỏng theo cocoa-dev mailing list archives

@interface NSString (cppstring_additions) 
+(NSString*) stringWithwstring:(const std::wstring&)string; 
+(NSString*) stringWithstring:(const std::string&)string; 
-(std::wstring) getwstring; 
-(std::string) getstring; 
@end 

@implementation NSString (cppstring_additions) 

#if TARGET_RT_BIG_ENDIAN 
const NSStringEncoding kEncoding_wchar_t = CFStringConvertEncodingToNSStringEncoding(kCFStringEncodingUTF32BE); 
#else 
const NSStringEncoding kEncoding_wchar_t = CFStringConvertEncodingToNSStringEncoding(kCFStringEncodingUTF32LE); 
#endif 

+(NSString*) stringWithwstring:(const std::wstring&)ws 
{ 
    char* data = (char*)ws.data(); 
    unsigned size = ws.size() * sizeof(wchar_t); 

    NSString* result = [[NSString alloc] initWithBytes:data length:size encoding:kEncoding_wchar_t]; 
    return result; 
} 
+(NSString*) stringWithstring:(const std::string&)s 
{ 
    NSString* result = [[NSString alloc] initWithUTF8String:s.c_str()]; 
    return result; 
} 

-(std::wstring) getwstring 
{ 
    NSData* asData = [self dataUsingEncoding:kEncoding_wchar_t]; 
    return std::wstring((wchar_t*)[asData bytes], [asData length]/sizeof(wchar_t)); 
} 
-(std::string) getstring 
{ 
    return [self UTF8String]; 
} 

@end 

Với rằng tại chỗ (và thích hợp #import ed), bạn có thể:

NSString* result = [NSString stringWithstring:param]; 
string convertedBack = [result getstring]; 

Và tương tự cho std::wstring, mà là nhiều hơn tiện dụng.

Answer 3

Tôi cũng đã phát hiện ra rằng:

NSString *nsString = [NSString stringWithFormat:@"%s",standardString]; 

trình giống như một nhà vô địch.

Answer 4

NSString* mystring = [NSString stringWithUTF8String:stdstring.c_str()]; 

Answer 5

Apple hiện có cách mới mà họ muốn bạn thực hiện chuyển đổi này. Trong XCode7, tôi sử dụng tùy chọn Edit> Convert> To Modern Objective C Syntax ... để tìm ra điều này. Nó sử dụng ký hiệu @ viết tắt.

std::string sCPPString = "Hello World!"; 
NSString *sAppleString = @(sCPPString.c_str()); 

Answer 6

Dưới đây là đoạn mã/example:

string str_simple = "HELLO WORLD"; 

//string to NSString 
NSString *stringinObjC = [NSString stringWithCString:str_simple.c_str() 
           encoding:[NSString defaultCStringEncoding]];    
NSLog(stringinObjC);