Sử dụng terraform để thiết lập hàm lambda được kích hoạt bởi nguồn sự kiện được lập lịch

Question

Tôi muốn chạy hàm lambda AWS cứ 5 phút một lần. Trong Bảng điều khiển quản lý AWS, điều này rất dễ thiết lập, trong tab "Nguồn sự kiện" của hàm lambda, nhưng làm cách nào để thiết lập nó với Terraform?

Tôi đã cố gắng sử dụng an aws_lambda_event_source_mapping resource, nhưng hóa ra là the API it uses chỉ hỗ trợ các sự kiện từ Kinesis và DynamoDB. Khi tôi cố gắng sử dụng nó với nguồn sự kiện được lên lịch, hãy tạo thời gian.

Answer 1

Bạn có thể sử dụng tài nguyên aws_cloudwatch_event_target để buộc nguồn sự kiện theo lịch (quy tắc sự kiện) vào hàm lambda của bạn. Bạn cần phải cho phép nó để gọi hàm lambda của bạn; bạn có thể sử dụng tài nguyên aws_lambda_permission cho việc này.

Ví dụ:

resource "aws_lambda_function" "check_foo" { 
    filename = "check_foo.zip" 
    function_name = "checkFoo" 
    role = "arn:aws:iam::424242:role/something" 
    handler = "index.handler" 
} 

resource "aws_cloudwatch_event_rule" "every_five_minutes" { 
    name = "every-five-minutes" 
    description = "Fires every five minutes" 
    schedule_expression = "rate(5 minutes)" 
} 

resource "aws_cloudwatch_event_target" "check_foo_every_five_minutes" { 
    rule = "${aws_cloudwatch_event_rule.every_five_minutes.name}" 
    target_id = "check_foo" 
    arn = "${aws_lambda_function.check_foo.arn}" 
} 

resource "aws_lambda_permission" "allow_cloudwatch_to_call_check_foo" { 
    statement_id = "AllowExecutionFromCloudWatch" 
    action = "lambda:InvokeFunction" 
    function_name = "${aws_lambda_function.check_foo.function_name}" 
    principal = "events.amazonaws.com" 
    source_arn = "${aws_cloudwatch_event_rule.every_five_minutes.arn}" 
} 

Answer 2

Trong giao diện điều khiển, tôi có thể thấy như sau:

Mặc dù nó nói tình trạng quy tắc được "kích hoạt", tôi vẫn phải kích hoạt kích hoạt chính nó. Không chắc tại sao Terraform lại không làm điều này.