Chuyển đổi các chức năng của kiểu `a -> b` thành các kiểu` String -> String` trong Haskell

Question

Ý định của tôi rất đơn giản. Tôi muốn bọc các chức năng của loại a -> b vào String -> String (để một loạt các hàm không đồng nhất có thể được đưa vào danh sách). Vì vậy, tôi viết:

wrap :: (Read a, Show b) => (a -> b) -> (String -> String) 
wrap f = \s -> show $ f (read s :: a) 

Tuy nhiên, ghc khiếu nại:

Could not deduce (Read a1) arising from a use of `read' 
from the context (Read a, Show b) 
    bound by the type signature for 
      wrap :: (Read a, Show b) => (a -> b) -> String -> String 

Tôi muốn biết lý do tại sao mảnh của tôi về mã sẽ không hoạt động và những loại hacks là cần thiết để đạt được mục tiêu của tôi?

Cảm ơn.

Answer 1

Mã của bạn sẽ không hoạt động vì Haskell không tái sử dụng hoặc phạm vi biến loại; các a trong wrap :: (Read a, Show b) => (a -> b) -> (String -> String) là hoàn toàn khác nhau a từ một trong read s :: a (và cả hai đều được định lượng phổ dụng). Đây là nguồn của a1 trong thông báo lỗi; GHC là alpha-chuyển đổi chương trình để

wrap :: (Read a, Show b) => (a -> b) -> (String -> String) 
wrap f = \s -> show $ f (read s :: a1) 

Tuy nhiên, loại lập luận f 's được cố định bên trong wrap, vì vậy chỉ đơn giản là loại bỏ các loại chú thích hoạt động tốt. Chức năng của bạn trở nên

wrap :: (Read a, Show b) => (a -> b) -> (String -> String) 
wrap f = \s -> show $ f (read s) 
    -- Or wrap f = show . f . read 

Và bạn có thể sử dụng nó:

ghci> map ($ "42") [wrap (+ (7 :: Integer)), wrap (* (2.0 :: Double))] 
["49","84.0"] 

Lưu ý rằng điều này có nghĩa rằng read s có một kiểu bạn không thể viết xuống. Trong Haskell 2010 (hoặc 98), cách duy nhất để giải quyết vấn đề này là sử dụng một hàm như asTypeOf :: a -> a -> a; asTypeOf chỉ là const, nhưng nhờ chữ ký kiểu của nó, nó ràng buộc đối số đầu tiên, được trả về của nó có cùng kiểu với thứ hai của nó. Sau đó, tất nhiên, bạn sẽ phải gợi ý một biến loại a. Sau đây sẽ làm việc cho điều đó:

wrap :: (Read a, Show b) => (a -> b) -> (String -> String) 
wrap f = \s -> show $ f (read s `asTypeOf` fInput) 
    where fInput = undefined 
     fOutput = f fInput -- I still can't give this a type signature 

Trong GHC, để tránh điều này, bạn có thể bật the ScopedTypeVariables extension; với điều đó, nếu bạn rõ ràng đủ điều kiện cho tất cả các biến loại của bạn với một forall, chúng sẽ được sắp xếp giống như các tên mức giá trị. Sau đó, mã của bạn sẽ trở thành

{-# LANGUAGE ScopedTypeVariables #-} 
wrap :: forall a b. (Read a, Show b) => (a -> b) -> (String -> String) 
wrap f = \s -> show $ f (read s :: a) 

Nhưng hãy nhớ, bạn không cần bất kỳ chú thích kiểu nào cho ví dụ đơn giản này.

Answer 2

Để xác định loại read s một cách rõ ràng, bạn sẽ cần một cái gì đó giống như ScopedTypeVariables:

{-# LANGUAGE ScopedTypeVariables #-} 
... 
wrap :: forall a b. (Read a, Show b) => (a -> b) -> (String -> String) 
wrap f = \s -> show $ f (read s :: a) 

Kể từ nếu không :: a chú thích bên trong hàm dùng để chỉ một loại khác nhau từ a trong chữ ký kiểu (nó ngầm nghĩa là :: forall a. a). Nhưng lưu ý rằng bạn cũng có thể chỉ cần thả chú thích loại hoàn toàn:

wrap :: (Read a, Show b) => (a -> b) -> (String -> String) 
wrap f = \s -> show $ f (read s) 

Vì loại read s có thể được suy ra. Điều đó cũng cho phép bạn đơn giản hóa nội dung thành

wrap f = show . f . read