Sql Server xác định người dùng định nghĩa chức năng

Question

tôi có chức năng người dùng định nghĩa sau đây:

create function [dbo].[FullNameLastFirst] 
(
    @IsPerson bit, 
    @LastName nvarchar(100), 
    @FirstName nvarchar(100) 
) 
returns nvarchar(201) 
as 
begin 
    declare @Result nvarchar(201) 
    set @Result = (case when @IsPerson = 0 then @LastName else case when @FirstName = '' then @LastName else (@LastName + ' ' + @FirstName) end end) 
    return @Result 
end 

Tôi không thể tạo ra một chỉ số trên một cột tính sử dụng chức năng này vì nó là không xác định. Ai đó có thể giải thích tại sao nó không xác định và cuối cùng làm thế nào để sửa đổi để làm cho nó xác định? Cảm ơn

Answer 1

Bạn chỉ cần tạo nó with schemabinding.

Máy chủ SQL sau đó sẽ xác minh xem nó có đáp ứng các tiêu chí được coi là xác định hay không (mà nó không truy cập bất kỳ bảng bên ngoài hoặc sử dụng các hàm không xác định như getdate()).

Bạn có thể xác nhận rằng nó làm việc với

SELECT OBJECTPROPERTY(OBJECT_ID('[dbo].[FullNameLastFirst]'), 'IsDeterministic') 

Thêm tùy chọn schemabinding mã ban đầu của bạn hoạt động tốt nhưng một phiên bản hơi đơn giản sẽ là.

CREATE FUNCTION [dbo].[FullNameLastFirst] (@IsPerson BIT, 
              @LastName NVARCHAR(100), 
              @FirstName NVARCHAR(100)) 
RETURNS NVARCHAR(201) 
WITH SCHEMABINDING 
AS 
    BEGIN 
     RETURN CASE 
       WHEN @IsPerson = 0 
        OR @FirstName = '' THEN @LastName 
       ELSE @LastName + ' ' + @FirstName 
      END 
    END 

Answer 2

Bạn cần phải khai báo User Defined Function với SchemaBinding

create function [dbo].[FullNameLastFirst] 
( 
    @IsPerson bit, 
    @LastName nvarchar(100), 
    @FirstName nvarchar(100) 
) 
returns nvarchar(201) 
with schemabinding 
as 
begin 
    declare @Result nvarchar(201) 
    set @Result = (case when @IsPerson = 0 then @LastName else case when @FirstName = '' then @LastName else (@LastName + ' ' + @FirstName) end end) 
    return @Result 
end 


create table Person 
(
isperson bit, 
lastname nvarchar(100), 
firstname nvarchar(100), 
fullname as [dbo].[FullNameLastFirst] (isperson, lastname, firstname) 
) 
go 
insert into person(isperson, lastname, firstname) values (1,'Firstname', 'Surname') 
go 

create index ix1_person on person(fullname) 
go 

select fullname from Person with (index=ix1_person) where fullname = 'Firstname Surname' 
go